/*
 * an arduino sketch to interface with a ps/2 mouse.
 * Also uses serial protocol to talk back to the host
 * and report what it finds.
 
 colors on my mouse
 data white
 clck black 
 gnd green
 vcc red
 
 with ic :
 "emc" em84510fp
 9952w bc9cn3


data transmission frame
Bit          Function
1   Start bit ( always 0 )
2-9 Data bits ( D0 - D7 )
10  Parity bit ( odd parity )
11  Stop bit ( always 1 )


*/

#define verbose // for verbose output
unsigned char msInitSequence[6];




/*
 * Pin 5 is the mouse data pin, pin 6 is the clock pin
 * Feel free to use whatever pins are convenient.
 */
#define MDATA 5
#define MCLK 6

/*
 * according to some code I saw, these functions will
 * correctly set the mouse clock and data pins for
 * various conditions.
 */
void gohi(int pin)
{
  pinMode(pin, INPUT);
  digitalWrite(pin, HIGH);
}

void golo(int pin)
{
  pinMode(pin, OUTPUT);
  digitalWrite(pin, LOW);
}


/* PRECONDITION : clock is HIGH */
/* sends a single bit and returns with clock high */
void sendBit(char bit) {

    if (bit) {
      gohi(MDATA);
    } 
    else {
      golo(MDATA);
    }
    /* wait for clock cycle */
    while (digitalRead(MCLK) == LOW)
      ;
    while (digitalRead(MCLK) == HIGH)
      ;
}

/* reads a single bit and returns with clock low */
char readBit() {
  char tmp = 0x00;
  while (digitalRead(MCLK) == HIGH)
    ;
  if (digitalRead(MDATA) == HIGH) 
    tmp = 0x01;

  while (digitalRead(MCLK) == LOW)
    ;

  return tmp;
}


void mouse_write(char data)
{
  char i;
  char parity = 1;

/* If EM84510 is not transmitting or if the system choose to */
/* override the output, the system force CLK to an inactive  */
/* level for a period of not less than 100μ sec while */
/* preparing for output. When the system is ready to output  */
/* start bit (0), it allows CLK go to active level. */

  /* put pins in output mode */
  gohi(MDATA);
  gohi(MCLK);
  delayMicroseconds(200);

  /* start bit */
  gohi(MCLK); // get the clock going
  sendBit(0);

  for (i=0; i < 8; i++) {
    char bit = (data>>i) & 0x01 ;
    sendBit(bit);
    parity = parity ^ (bit);
  }  

  /* parity */
  sendBit(parity);
  /* stop bit */
  sendBit(1);

  /* wait for mouse to switch modes */
  while ((digitalRead(MCLK) == LOW) || (digitalRead(MDATA) == LOW))
    ;
  /* put a hold on the incoming data. */
  golo(MCLK);
}

/*
 * Get a byte of data from the mouse
 */
char mouse_read(void)
{
  char data = 0x00;
  int i;

  /* start the clock */
  gohi(MCLK);
  gohi(MDATA);
  delayMicroseconds(50);

  readBit(); // startbit

  for (i=0; i < 8; i++) {
    data = data | (readBit()<<i);
  }

  readBit(); /* eat parity bit, which we ignore */
  readBit();   /* eat stop bit */

  /* put a hold on the incoming data. */
  golo(MCLK);
  return data;
}


char writeAndGetResponse(char data) {
#ifdef verbose
  Serial.print("sending :  ");
  Serial.print((unsigned char)data, HEX);
  Serial.print("\t");
#endif   

  mouse_write( data );
  return response();
}

char response() {
  char data = mouse_read();
#ifdef verbose
  Serial.print("echo ");
  Serial.print((unsigned char)data, HEX);
  Serial.print(" from mouse\n");
#endif
  return data;
}

void msMode() {
  // sequence for ms mode (3 button + scroll)
  // this is a entering procedure and i guess it will
  // work with other mice/ICs as its problably stadard ps2
  // And using an array were just a quick way to handle them
  msInitSequence[0] =0xF3;
  msInitSequence[1] =0xC8;
  msInitSequence[2] =0xF3;
  msInitSequence[3] =0x64;
  msInitSequence[4] =0xF3;
  msInitSequence[5] =0x50;
  msInitSequence[6] =0xF2;

  int i;
  for(i=0;i<7;i++) 
    writeAndGetResponse(msInitSequence[i]);
  if (response()==3) {
#ifdef verbose
    Serial.print(" ms mode\n"); 
#endif
  }
}

void mouse_init()
{
  gohi(MCLK);
  gohi(MDATA);
#ifdef verbose
  Serial.print("Sending reset to mouse\n");
#endif
  writeAndGetResponse(0xff);
  response();
  response();

  msMode();

/* Remote Mode: */
/* Data is transmitted only in response to a Read Data command. */
#ifdef verbose
  Serial.print("Sending remote mode code\n");
#endif
  writeAndGetResponse(0xF0);  /* remote mode */
/*   delayMicroseconds(100); */
}

void showMStat(char mstat) {
  int i;
  char bit = 0x01;
  for(i = 0; i<8; i++) {
    if(mstat&bit) {
      switch(i) {
      case 0:
        Serial.print("left button pressed \t");
        break;
      case 1:
        Serial.print("Right button pressed \t");
        break;
      case 2:
        Serial.print("Middle Button Pressed \t");
        break;
      case 3:
        //        Serial.print(" Reserve ...\t");
        break;
      case 4:
        Serial.print(" X data negative \t");
        break;
      case 5:
        Serial.print("Y data negative \t");
        break;
      case 6:
        Serial.print("X data overflow \t");
        break;
      case 7:
        Serial.print("Y data overflow \t");
        break;
      }
    }
    bit = bit<<1;
  } 
}

void setup()
{
  Serial.begin(9600);


  mouse_init();
}

/*
 * get a reading from the mouse and report it back to the
 * host via the serial line.
 */
void loop()
{
  char mstat;
  char mx;
  char my;
  char mz;
  /* get a reading from the mouse */
  writeAndGetResponse(0xEB);  /* give me data! */

  mstat = mouse_read();
  mx = mouse_read();
  my = mouse_read();
  mz = mouse_read();

  /* send the data back up */


  Serial.print("\nX=");
  Serial.print(mx, DEC);
  Serial.print("\tY=");
  Serial.print(my, DEC);
  Serial.print("\tZ=");
  Serial.print(mz, DEC);
  //  Serial.println();
  showMStat(mstat);
  delay(5000);/* twiddle */
}